Gecko [ betsfootball.net ]

Name	Size	Permission	Date
App	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
Archive	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
Attribute	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
B	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
CPAN	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
Carp	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
Class	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
Compress	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
Config	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
DBM_Filter	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
Devel	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
Digest	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
Encode	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
Exporter	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
ExtUtils	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
File	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
Filter	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
Getopt	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
HTTP	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
I18N	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
IO	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
IPC	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
JSON	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
Locale	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
Math	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
Memoize	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
Module	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
Net	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
Params	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
Parse	[ DIR ]	drwxr-xr-x	2023-07-12 09:40
Perl	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
PerlIO	[ DIR ]	drwxr-xr-x	2023-07-12 09:40
Pod	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
Search	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
TAP	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
Term	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
Test	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
Test2	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
Text	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
Thread	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
Tie	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
Time	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
Unicode	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
User	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
autodie	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
encoding	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
overload	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
pod	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
unicore	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
version	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
warnings	[ DIR ]	drwxr-xr-x	2025-04-07 20:15
AnyDBM_File.pm	2.56 KB	-rw-r--r--	2023-11-25 20:59
AutoLoader.pm	15.43 KB	-rw-r--r--	2023-11-25 20:59
AutoSplit.pm	19.18 KB	-rw-r--r--	2023-11-25 20:59
Benchmark.pm	30.3 KB	-rw-r--r--	2023-11-25 20:59
CORE.pod	3.11 KB	-rw-r--r--	2023-11-25 20:59
CPAN.pm	144.5 KB	-rw-r--r--	2023-11-25 20:59
Carp.pm	35.14 KB	-rw-r--r--	2023-11-25 20:59
DB.pm	18.48 KB	-rw-r--r--	2023-11-25 20:59
DBM_Filter.pm	14.05 KB	-rw-r--r--	2023-11-25 20:59
Digest.pm	10.96 KB	-rw-r--r--	2023-11-25 20:59
DirHandle.pm	2.04 KB	-rw-r--r--	2023-11-25 20:59
Dumpvalue.pm	17.25 KB	-rw-r--r--	2023-11-25 20:59
English.pm	4.65 KB	-rw-r--r--	2023-11-25 20:59
Env.pm	5.44 KB	-rw-r--r--	2023-11-25 20:59
Exporter.pm	18.76 KB	-rw-r--r--	2023-11-25 20:59
Fatal.pm	57.7 KB	-rw-r--r--	2023-11-25 20:59
FileCache.pm	5.42 KB	-rw-r--r--	2023-11-25 20:59
FileHandle.pm	6.63 KB	-rw-r--r--	2023-11-25 20:59
FindBin.pm	4.51 KB	-rw-r--r--	2023-11-25 20:59
Internals.pod	2.51 KB	-rw-r--r--	2023-11-25 20:59
Memoize.pm	35.34 KB	-rw-r--r--	2023-11-25 20:59
NEXT.pm	18.54 KB	-rw-r--r--	2023-11-25 20:59
PerlIO.pm	13.92 KB	-rw-r--r--	2023-11-25 20:59
Safe.pm	24.76 KB	-rw-r--r--	2023-11-25 20:59
SelectSaver.pm	1.05 KB	-rw-r--r--	2023-11-25 20:59
SelfLoader.pm	17.27 KB	-rw-r--r--	2023-11-25 20:59
Symbol.pm	4.79 KB	-rw-r--r--	2023-11-25 20:59
Test.pm	29.34 KB	-rw-r--r--	2023-11-25 20:59
Test2.pm	6.24 KB	-rw-r--r--	2023-11-25 20:59
Thread.pm	8.09 KB	-rw-r--r--	2023-11-25 20:59
UNIVERSAL.pm	6.61 KB	-rw-r--r--	2023-11-25 20:59
XSLoader.pm	11.13 KB	-rw-r--r--	2023-11-25 20:59
_charnames.pm	34.84 KB	-rw-r--r--	2023-11-25 20:59
autodie.pm	12.14 KB	-rw-r--r--	2023-11-25 20:59
autouse.pm	4.14 KB	-rw-r--r--	2023-11-25 20:59
base.pm	10.7 KB	-rw-r--r--	2023-11-25 20:59
bigfloat.pm	21.45 KB	-rw-r--r--	2023-11-25 20:59
bigint.pm	22.7 KB	-rw-r--r--	2023-11-25 20:59
bignum.pm	27.56 KB	-rw-r--r--	2023-11-25 20:59
bigrat.pm	20.64 KB	-rw-r--r--	2023-11-25 20:59
blib.pm	2.01 KB	-rw-r--r--	2023-11-25 20:59
builtin.pm	8.84 KB	-rw-r--r--	2023-11-25 20:59
bytes.pm	3.69 KB	-rw-r--r--	2023-11-25 20:59
bytes_heavy.pl	758 B	-rw-r--r--	2023-11-25 20:59
charnames.pm	20.56 KB	-rw-r--r--	2023-11-25 20:59
constant.pm	14.38 KB	-rw-r--r--	2023-11-25 20:59
deprecate.pm	4.92 KB	-rw-r--r--	2023-11-25 20:59
diagnostics.pm	18.88 KB	-rw-r--r--	2023-11-25 20:59
dumpvar.pl	15.19 KB	-rw-r--r--	2023-11-25 20:59
experimental.pm	8.12 KB	-rw-r--r--	2023-11-25 20:59
feature.pm	51.6 KB	-rw-r--r--	2023-11-25 20:59
fields.pm	9.25 KB	-rw-r--r--	2023-11-25 20:59
filetest.pm	3.91 KB	-rw-r--r--	2023-11-25 20:59
if.pm	3.55 KB	-rw-r--r--	2023-11-25 20:59
integer.pm	3.18 KB	-rw-r--r--	2023-11-25 20:59
less.pm	3.13 KB	-rw-r--r--	2023-11-25 20:59
locale.pm	4.77 KB	-rw-r--r--	2023-11-25 20:59
meta_notation.pm	2.02 KB	-rw-r--r--	2023-11-25 20:59
ok.pm	967 B	-rw-r--r--	2023-11-25 20:59
open.pm	8.3 KB	-rw-r--r--	2023-11-25 20:59
overload.pm	52.22 KB	-rw-r--r--	2023-11-25 20:59
overloading.pm	1.77 KB	-rw-r--r--	2023-11-25 20:59
parent.pm	2.64 KB	-rw-r--r--	2023-11-25 20:59
perl5db.pl	310.05 KB	-rw-r--r--	2023-11-25 20:59
perlfaq.pm	77 B	-rw-r--r--	2023-11-25 20:59
sigtrap.pm	8.53 KB	-rw-r--r--	2023-11-25 20:59
sort.pm	2.92 KB	-rw-r--r--	2023-11-25 20:59
strict.pm	4.67 KB	-rw-r--r--	2023-11-25 20:59
subs.pm	945 B	-rw-r--r--	2023-11-25 20:59
utf8.pm	10.5 KB	-rw-r--r--	2023-11-25 20:59
vars.pm	2.4 KB	-rw-r--r--	2023-11-25 20:59
version.pm	1.93 KB	-rw-r--r--	2023-11-25 20:59
version.pod	9.6 KB	-rw-r--r--	2023-11-25 20:59
vmsish.pm	4.21 KB	-rw-r--r--	2023-11-25 20:59
warnings.pm	54.61 KB	-rw-r--r--	2023-11-25 20:59

Rename

package Env;

our $VERSION = '1.05';

=head1 NAME

Env - perl module that imports environment variables as scalars or arrays

=head1 SYNOPSIS

use Env;
    use Env qw(PATH HOME TERM);
    use Env qw($SHELL @LD_LIBRARY_PATH);

=head1 DESCRIPTION

Perl maintains environment variables in a special hash named C<%ENV>.  For
when this access method is inconvenient, the Perl module C<Env> allows
environment variables to be treated as scalar or array variables.

The C<Env::import()> function ties environment variables with suitable
names to global Perl variables with the same names.  By default it
ties all existing environment variables (C<keys %ENV>) to scalars.  If
the C<import> function receives arguments, it takes them to be a list of
variables to tie; it's okay if they don't yet exist. The scalar type
prefix '$' is inferred for any element of this list not prefixed by '$'
or '@'. Arrays are implemented in terms of C<split> and C<join>, using
C<$Config::Config{path_sep}> as the delimiter.

After an environment variable is tied, merely use it like a normal variable.
You may access its value

@path = split(/:/, $PATH);
    print join("\n", @LD_LIBRARY_PATH), "\n";

or modify it

$PATH .= ":/any/path";
    push @LD_LIBRARY_PATH, $dir;

however you'd like. Bear in mind, however, that each access to a tied array
variable requires splitting the environment variable's string anew.

The code:

use Env qw(@PATH);
    push @PATH, '/any/path';

is almost equivalent to:

use Env qw(PATH);
    $PATH .= ":/any/path";

except that if C<$ENV{PATH}> started out empty, the second approach leaves
it with the (odd) value "C<:/any/path>", but the first approach leaves it with
"C</any/path>".

To remove a tied environment variable from
the environment, assign it the undefined value

undef $PATH;
    undef @LD_LIBRARY_PATH;

=head1 LIMITATIONS

On VMS systems, arrays tied to environment variables are read-only. Attempting
to change anything will cause a warning.

=head1 AUTHOR

Chip Salzenberg E<lt>F<chip@fin.uucp>E<gt>
and
Gregor N. Purdy E<lt>F<gregor@focusresearch.com>E<gt>

=cut

sub import {
    my ($callpack) = caller(0);
    my $pack = shift;
    my @vars = grep /^[\$\@]?[A-Za-z_]\w*$/, (@_ ? @_ : keys(%ENV));
    return unless @vars;

@vars = map { m/^[\$\@]/ ? $_ : '$'.$_ } @vars;

eval "package $callpack; use vars qw(" . join(' ', @vars) . ")";
    die $@ if $@;
    foreach (@vars) {
	my ($type, $name) = m/^([\$\@])(.*)$/;
	if ($type eq '$') {
	    tie ${"${callpack}::$name"}, Env, $name;
	} else {
	    if ($^O eq 'VMS') {
		tie @{"${callpack}::$name"}, Env::Array::VMS, $name;
	    } else {
		tie @{"${callpack}::$name"}, Env::Array, $name;
	    }
	}
    }
}

sub TIESCALAR {
    bless \($_[1]);
}

sub FETCH {
    my ($self) = @_;
    $ENV{$$self};
}

sub STORE {
    my ($self, $value) = @_;
    if (defined($value)) {
	$ENV{$$self} = $value;
    } else {
	delete $ENV{$$self};
    }
}

######################################################################

package Env::Array;
 
use Config;
use Tie::Array;

@ISA = qw(Tie::Array);

my $sep = $Config::Config{path_sep};

sub TIEARRAY {
    bless \($_[1]);
}

sub FETCHSIZE {
    my ($self) = @_;
    return 1 + scalar(() = $ENV{$$self} =~ /\Q$sep\E/g);
}

sub STORESIZE {
    my ($self, $size) = @_;
    my @temp = split($sep, $ENV{$$self});
    $#temp = $size - 1;
    $ENV{$$self} = join($sep, @temp);
}

sub CLEAR {
    my ($self) = @_;
    $ENV{$$self} = '';
}

sub FETCH {
    my ($self, $index) = @_;
    return (split($sep, $ENV{$$self}))[$index];
}

sub STORE {
    my ($self, $index, $value) = @_;
    my @temp = split($sep, $ENV{$$self});
    $temp[$index] = $value;
    $ENV{$$self} = join($sep, @temp);
    return $value;
}

sub EXISTS {
    my ($self, $index) = @_;
    return $index < $self->FETCHSIZE;
}

sub DELETE {
    my ($self, $index) = @_;
    my @temp = split($sep, $ENV{$$self});
    my $value = splice(@temp, $index, 1, ());
    $ENV{$$self} = join($sep, @temp);
    return $value;
}

sub PUSH {
    my $self = shift;
    my @temp = split($sep, $ENV{$$self});
    push @temp, @_;
    $ENV{$$self} = join($sep, @temp);
    return scalar(@temp);
}

sub POP {
    my ($self) = @_;
    my @temp = split($sep, $ENV{$$self});
    my $result = pop @temp;
    $ENV{$$self} = join($sep, @temp);
    return $result;
}

sub UNSHIFT {
    my $self = shift;
    my @temp = split($sep, $ENV{$$self});
    my $result = unshift @temp, @_;
    $ENV{$$self} = join($sep, @temp);
    return $result;
}

sub SHIFT {
    my ($self) = @_;
    my @temp = split($sep, $ENV{$$self});
    my $result = shift @temp;
    $ENV{$$self} = join($sep, @temp);
    return $result;
}

sub SPLICE {
    my $self = shift;
    my $offset = shift;
    my $length = shift;
    my @temp = split($sep, $ENV{$$self});
    if (wantarray) {
	my @result = splice @temp, $offset, $length, @_;
	$ENV{$$self} = join($sep, @temp);
	return @result;
    } else {
	my $result = scalar splice @temp, $offset, $length, @_;
	$ENV{$$self} = join($sep, @temp);
	return $result;
    }
}

######################################################################

package Env::Array::VMS;
use Tie::Array;

@ISA = qw(Tie::Array);
 
sub TIEARRAY {
    bless \($_[1]);
}

sub FETCHSIZE {
    my ($self) = @_;
    my $i = 0;
    while ($i < 127 and defined $ENV{$$self . ';' . $i}) { $i++; };
    return $i;
}

sub FETCH {
    my ($self, $index) = @_;
    return $ENV{$$self . ';' . $index};
}

sub EXISTS {
    my ($self, $index) = @_;
    return $index < $self->FETCHSIZE;
}

sub DELETE { }