Gecko [ betsfootball.net ]

Name	Size	Permission	Date
_bootctl	2.84 KB	-rw-r--r--	2025-03-06 11:43
_busctl	9.43 KB	-rw-r--r--	2025-03-06 11:43
_curl	15.32 KB	-rw-r--r--	2025-03-09 10:45
_dpkg-parsechangelog	1.38 KB	-rw-r--r--	2023-05-11 02:04
_hostnamectl	2.73 KB	-rw-r--r--	2025-03-06 11:43
_journalctl	7.2 KB	-rw-r--r--	2025-03-06 11:43
_kernel-install	779 B	-rw-r--r--	2025-03-06 11:43
_localectl	3.69 KB	-rw-r--r--	2025-03-06 11:43
_loginctl	6.25 KB	-rw-r--r--	2025-03-06 11:43
_networkctl	2.11 KB	-rw-r--r--	2025-03-06 11:43
_sd_hosts_or_user_at_host	128 B	-rw-r--r--	2025-03-06 11:43
_sd_outputmodes	318 B	-rw-r--r--	2025-03-06 11:43
_sd_unit_files	263 B	-rw-r--r--	2025-03-06 11:43
_systemctl	20.89 KB	-rw-r--r--	2025-03-06 14:56
_systemd	3.76 KB	-rw-r--r--	2025-03-06 11:43
_systemd-analyze	5.06 KB	-rw-r--r--	2025-03-06 11:43
_systemd-delta	633 B	-rw-r--r--	2025-03-06 11:43
_systemd-inhibit	1.15 KB	-rw-r--r--	2025-03-06 11:43
_systemd-path	330 B	-rw-r--r--	2025-03-06 11:43
_systemd-run	4.25 KB	-rw-r--r--	2025-03-06 11:43
_systemd-tmpfiles	744 B	-rw-r--r--	2025-03-06 11:43
_timedatectl	2.12 KB	-rw-r--r--	2025-03-06 11:43
_udevadm	8.06 KB	-rw-r--r--	2025-03-06 11:43

Rename

#compdef timedatectl
# SPDX-License-Identifier: LGPL-2.1-or-later

_timedatectl_set-timezone(){
    local -a _timezones
    _timezones=( ${(f)"$(_call_program timezones "${service}" list-timezones)"} )
    compadd "$_timezones[@]"
}

_timedatectl_set-time(){
    _message "YYYY-MM-DD HH:MM:SS"
}

_timedatectl_set-local-rtc(){
    local -a _options
    _options=(
        '0:Maintain RTC in universal time'
        '1:Maintain RTC in local time'
    )
    _describe options _options
}

_timedatectl_set-ntp(){
    local -a _options
    _options=(
        '0:Disable NTP based network time configuration'
        '1:Enable NTP based network time configuration'
    )
    _describe options _options
}

_timedatectl_command(){
    local -a _timedatectl_cmds
    _timedatectl_cmds=(
        'status:Show current time settings'
        'set-time:Set system time'
        'set-timezone:Set system timezone'
        'list-timezones:Show known timezones'
        'timesync-status:Show status of systemd-timesyncd'
        'show-timesync:Show properties of systemd-timesyncd'
        'set-local-rtc:Control whether RTC is in local time'
        'set-ntp:Control whether NTP is enabled'
    )
    if (( CURRENT == 1 )); then
        _describe -t commands 'timedatectl command' _timedatectl_cmds
    else
        local curcontext="$curcontext"
        cmd="${${_timedatectl_cmds[(r)$words[1]:*]%%:*}}"
        if (( $#cmd )); then
            if (( $+functions[_timedatectl_$cmd] )); then
                _timedatectl_$cmd
            else
                _message "no more options"
            fi
        else
            _message "unknown timedatectl command: $words[1]"
        fi
    fi
}

_arguments -s \
    {-h,--help}'[Show this help]' \
    '--version[Show package version]' \
    '--adjust-system-clock[Adjust system clock when changing local RTC mode]' \
    '--no-pager[Do not pipe output into a pager]' \
    '--no-ask-password[Do not prompt for password]' \
    {-H+,--host=}'[Operate on remote host]:userathost:_sd_hosts_or_user_at_host' \
    {-M+,--machine=}'[Operate on local container]:machines:_sd_machines' \
    '*::timedatectl commands:_timedatectl_command'